next up previous contents
Next: Commentaires Up: Calcul du champ de températures d'un tube épais Previous: Données du problème

Fichier de données

TITRE 'CALCUL THERMIQUE D UN TUBE ' ;                       
OPTION DIME 2 ELEM QUA4 MODE AXIS ;                                             
OPTION ECHO 0 ; SAUT LIGNE ;
*                                                                               
*---  CREATION DE LA GEOMETRIE:                                                 
*                                                                               
P1 = 0.05 0. ; P2 = 0.2  0.  ;
VEC1 = 0. 0.5 ;            
L1 = D 10 P1 P2 ;                     
SURF1  = L1 TRANS 1 VEC1 ;   
TRAC SURF1 ;                       
*                 
D1 = COTE 4 SURF1 ;                                                           
D3 = COTE 2 SURF1 ;                                                           
*  
*---  DONNEES DU PROBLEME DE THERMIQUE:                                         
*                                                                               
*---  MODELISATION:  
MOD1 = MODL SURF1 THERMIQUE ISOTROPE ;                                         
*                                                                               
*---  CARACTERISTIQUES DU MATERIAU:                                             
MAT1 = MATR MOD1 K 130. ;                                                       
*                                                                               
*---  MATRICE DE CONDUCTIVITE:                                                  
COND1 = CONDUCTIVITE MOD1 MAT1 ;      
*                                                                               
*---  CONDITIONS AUX LIMITES : TEMPERATURES IMPOSEES                 
CL1 = BLOQUE T D1 ;          
DCL1 = DEPI CL1 0. ;               
*                                                                               
*---  CHARGEMENT : FLUX IMPOSE                       
FLU1 = FLUX MOD1 100. D3 ;                     
*                                                                               
*---  ASSEMBLAGE DES PREMIER ET SECOND MEMBRES:                                 
CONTOT = COND1 ET CL1 ;                      
FLUTOT = DCL1 ET FLU1 ;                          
*                                                                               
*---  RESOLUTION:                                                               
CHTER1 = RESOUDRE CONTOT FLUTOT ;   
*
*--- POST TRAITEMENT
*
TITRE 'CHAMP DE TEMPERATURES' ;
TRAC CHTER1 SURF1 ;
*                                                 
TETA2 = EXTR CHTER1 T P2 ; 
TTHP2 = 0.213 ;
MESS 'TEMPERATURE THEORIQUE EN P2 :'TTHP2 ;
MESS 'TEMPERATURE CALCULEE EN P2 :'TETA2 ;
*
*--- FIN DU FICHIER 
FIN ;



mer 12 aoû 15:48:36 DFT 1998