Fichier de données

OPTI DIME 2 ELEM SEG2 MODE AXIS ;
*---------------------DONNEES---------------------*
PRES1 = 1.E5 ;
RAY1 = 2. ;
EPA1 = 0.01 ;
NUP = 0.3 ;
YOP = 2.1E11 ;
*--------------------GEOMETRIE--------------------*
P0 = 0. 0. ;
P1 = 0. RAY1 ;
P2 = RAY1 0. ;
L1 = C 24 P1 P0 P2 ; TRAC L1 ;
*------DEFINITION DU MODELE ET DU MATERIAU--------*
MOD1 = MODEL L1 MECANIQUE ELASTIQUE ISOTROPE COQ2 ;
MAT1 = MATER MOD1 YOUN YOP NU NUP ;
CAR1 = CARAC MOD1 EPAI EPA1 ;
MATTOT = MAT1 ET CAR1 ;
*--------------CONDITIONS LIMITES-----------------*
CL1 = SYMT DEPLA P1 P0 L1 1.E-4 ;
CLR1 = SYMT ROTA P1 P0 L1 1.E-4 ;
CL2 = SYMT DEPLA P2 P0 L1 1.E-4 ;
CLR2 = SYMT ROTA P2 P0 L1 1.E-4 ;
CLTOT = CL1 ET CLR1 ET CL2 ET CLR2 ;
*------------------CHARGEMENT---------------------*
CHA1 = PRESS COQUE MOD1 PRES1 NORM ;
VEC1 = VECT CHA1 5.E-6 FR FZ ROUGE ;
TRAC VEC1 L1 ;
*-------------MATRICE DE RIGIDITE-----------------*
RIG1 = RIGI MOD1 MATTOT ;
RIG1 = RIG1 ET CLTOT ;
*------------------RESOLUTION---------------------*
RES1 = RESO RIG1 CHA1 ;
*-------------------RESULTATS---------------------*
DUR = EXCO RES1 UR ;
DURMAX = MAXI (ABS DUR) ;
MESS 'DILATATION EN METRES :'DURMAX ;
*-------------------DEFORMEE----------------------*
DEF0 = DEFO L1 RES1 0. VERT ;
DEF1 = DEFO L1 RES1  ROUGE ;
TITRE 'DEFORMEE SOUS PRESSION INTERNE de 'PRES1'Pa' ;
TRAC (DEF0 ET DEF1) ;
FIN ;