next up previous contents
Next: Commentaires Up: Analyse modale Previous: Données du problème

Fichier de données

OPTI DIME 3 ELEM QUA4;

A1 = 0.4 ;
PI= 3.1415927 ;

*MAILLAGE
P1 = 0.  0.  0. ; P2 = 0. A1  0. ;
VEC1 = A1 0. 0. ;
L1 = D 12 P1 P2 ;
S1 = L1 TRAN 12 VEC1 ;

*MODELE ET PROPRIETES DE MATERIAUX
MOD1= MODEL S1 MECANIQUE ELASTIQUE COQ4;
MAT1= MATER MOD1 YOUN 7.E10 NU 0.3 RHO 4200. ;
CAR1= CARAC MOD1 EPAI 0.006 ;
MATTOT = MAT1 ET CAR1 ;

*CONDITIONS AUX LIMITES
CL1= BLOQ DEPLA ROTA L1 ;

*MATRICES DE RIGIDITE ET DE MASSE
RIG1= RIGI MOD1 MATTOT ; RIG1 = RIG1 ET CL1 ;
MAS1= MASS MOD1 MATTOT ;

*CALCUL DES MODES
TAB1= VIBR INTER 0. 100. MAS1  RIG1 IMPR TBAS ;
TAB2= TAB1.modes ;

*RESULTATS
F1= (TAB2.1).frequence ; 
F2= (TAB2.2).frequence ; 
MESS 'FREQUENCE 1 (HZ) :' F1;
MESS 'FREQUENCE 2 (HZ) :' F2;

*TRACE DES DEFORMEES MODALES
DEP1= (TAB2.1).deformee_modale ; DEF1= DEFO DEP1 S1 1. ROUGE;
DEP2= (TAB2.2).deformee_modale ; DEF2= DEFO DEP2 S1 1. VERT ;
DEF0= defo DEP1 S1 0.;
TITRE 'Deformees modales (MODE 1)' ;
TRAC  (DEF0 ET DEF1);
TITRE 'Deformees modales (MODE 2)' ;
TRAC  (DEF0 ET DEF2);

FIN;


mer 12 aoŻ 15:48:36 DFT 1998