next up previous contents
Next: Commentaires Up: Analyse statique linéaire Previous: Données du problème

Fichier de données

OPTI DIME 3 ELEM SEG2 OPTI TRID ;

*DONNEES
AMPF = -1000. ;
LON1 = 1. ;
DIA1 = 0.1 ;
RHOP = 7800. ;
NUP = 0.3 ;
YOP = 2.1E11 ;


*CALCUL DES DONNEES GEOMETRIQUES
S1 = PI*(DIA1**2)/4. ;
IY = PI*(DIA1**4)/64. ;
IZ = IY ;
IG = PI*(DIA1**4)/32. ;

*GEOMETRIE
P1 = 0. 0. 0.;
P2 = LON1 0. 0.;
L1 = D 10 P1 P2 ;

*DEFINITION DU MODELE ET DU MATERIAU
MOD1 = MODEL L1 MECANIQUE ELASTIQUE ISOTROPE POUT ;
MAT1 = MATER MOD1 YOUN YOP NU NUP RHO RHOP ;
CAR1 = CARAC MOD1 SECT S1 INRY IY INRZ IZ TORS IG ;
MATTOT = MAT1 ET CAR1 ;

*CONDITIONS LIMITES
CL1 = BLOQ DEPLA ROTA P1 ;

*CHARGEMENT
FOR1 = FORCE FY AMPF P2 ;

*MATRICE DE RIGIDITE
RIG1 = RIGI MOD1 MATTOT ;
RIG1 = RIG1 ET CL1 ;

*RESOLUTION 
RES1 = RESO RIG1 FOR1 ;

*RESULTATS
DY = EXCO RES1 UY ;
DYABS = ABS DY ;
DYMAX = MAXI DYABS ;
MESS 'FLECHE MAXIMALE EN METRES (F=1000N) :'DYMAX ;

*DEFORMEE
DEF0 = DEFO L1 RES1 0. VERT ;
DEF1 = DEFO L1 RES1  ROUGE ;
OEIL1 = 0. 0. 1000. ;
TRAC OEIL1 (DEF0 ET DEF1) ;

FIN;


mer 12 aoŻ 15:48:36 DFT 1998