next up previous contents
Next: Commentaires Up: Calcul thermo-mécanique Previous: Données du problème

Fichier de données

TITRE 'CALCUL THERMO-MECANIQUE' ;        
OPTION DIME 2 ELEM QUA8 MODE PLAN CONT ;      
OPTION ECHO 0 ; SAUT LIGNE ;
*                          
*---  CREATION DE LA GEOMETRIE:                 
A = 0.  0. ; B = 0.6 0. ;
C = 0.6 1. ; E = 0.  1. ;        
AB = D 6 A B ;                     
BC = D 10 B C ;                     
CE = D 6 C E ;                     
EA = D 10 E A ;                     
SURF1  = DALL AB BC CE EA PLAN ;   
TRAC SURF1 ;                       
*  
*-------------------  CALCUL THERMIQUE  ---------------------*          
*     
*---  MODELISATION:                                           
MOD1 = MODL SURF1 THERMIQUE ISOTROPE ;    
MOD1 = MODE SURF1 THERMIQUE ISOTROPE QUA8 ;
MOD2 = MODE (BC ET CE) CONVECTION ;
*                                                
*---  CARACTERISTIQUES DU MATERIAU:            
MAT1 = MATR MOD1 K 52. ;                 
MAT2 = MATR MOD2 H 750. ;                  
*                                                  
*---  CONDITIONS AUX LIMITES : TEMPERATURES IMPOSEES    
CL1 = BLOQUE T AB ;          
FCL1 = DEPI CL1 100. ;               
*                                            
*---  CHARGEMENT : FLUX DE CONVECTION                       
FLU1 = CONV MOD2 MAT2 T 0. ;   
*
*---  MATRICES DE CONDUCTIVITE:    
        
COND1 = COND MOD1 MAT1 ;      
COND2 = COND MOD2 MAT2 ;      
CONDTOT = COND1 ET COND2 ET CL1 ;      
*                                           
*---  ASSEMBLAGE DU SECOND MEMBRE: 
FLUTOT = FCL1 ET FLU1 ;                          
*                                            
*---  RESOLUTION:                          
CHTER1 = RESOU CONDTOT FLUTOT ;   
*
*--- POST TRAITEMENT
TITRE 'CHAMP DE TEMPERATURES (MAXI='(MAXI CHTER1)')' ;
TRAC CHTER1 SURF1 ;
*     
*-------------------  CALCUL MECANIQUE  ---------------------* 
*
*---  MODELISATION:                                    
MOD1 = MODL SURF1 THERMIQUE ISOTROPE ;             
MOD3 = MODE SURF1 MECANIQUE ELASTIQUE ISOTROPE QUA8 ;
*
*---  CARACTERISTIQUES DU MATERIAU:                  
MAT3 = MATR MOD3 YOUN 2.E11 NU 0.3 RHO 7800. ALPH 1.e-5 ;    
*
*---  CONDITIONS AUX LIMITES : 
CL3 = BLOQ DEPL (AB ET CE) ;
*
*---  CHARGEMENT : THERMIQUE ET PRESSION
SIGT3 = THET MOD3 CHTER1 MAT3 ;
F3 = BSIG MOD3 SIGT3 ;
PRES3 = PRESSION MASS MOD3 100.E6 EA ;
CHAR3 = F3 ET PRES3 ;
*
*---  RESOLUTION:                      
RIG3 = RIGI MOD3 MAT3 ;
RIGCL3 = RIG3 ET CL3 ;
DEP3 = RESOU RIGCL3 CHAR3 ;   
*
*--- POST TRAITEMENT
*DEFORMEE
DEF0 = DEFO SURF1 DEP3 0. BLAN ;
DEF1 = DEFO SURF1 DEP3    ROUG ;
TITR 'DEFORMEE APRES CHARGEMENT THERMIQUE ET PRESSION' ;
TRAC (DEF0 ET DEF1) ;
*
*CALCUL DES CONTRAINTES TOTALES ET MECANIQUES
SIGTOT3 = SIGMA MOD3 MAT3 DEP3 ;
SIGM3 = SIGTOT3 - SIGT3 ;
*
S_XX = (EXCO SMXX SIGM3)/1.e6 ;
TITR ' CONTRAINTES S_XX (MAXI=' (MAXI S_XX) 'MPa)' ;
TRAC MOD3 S_XX ;
S_YY = (EXCO SMYY SIGM3)/1.e6 ;
TITR ' CONTRAINTES S_YY (MAXI=' (MAXI S_YY) 'MPa)' ;
TRAC MOD3 S_YY ;
*
*--- FIN DU FICHIER 
FIN ;



mer 12 aoŻ 15:48:36 DFT 1998