Télécharger formation_debutant_3_mecanique.dgibi

Retour à la liste

* fichier : formation_debutant_3_mecanique.dgibi
*
************************************************************************
*      FORMATION DEBUTER AVEC CAST3M - CALCULS THERMO-MECANIQUES       *
*                                                                      *
* Modelisation du comportement thermo-mecanique d'une structure avec   *
* une cavite                                                           *
*                                                                      *
* Ce fichier est la partie 3 sur 3 de la formation debutant a Cast3M   *
*                                                                      *
* Partie 3 : calculs mecaniques                                        *
*            restitution des objets                                    *
*            elasticite lineaire, plasticite parfaite                  *
*            chargement thermique                                      *
*            caracteristiques variables                                *
*                                                                      *
************************************************************************
 
 
 
 
* RESTITUTION DES OBJETS CREES
* ----------------------------
OPTI 'REST' 'formation_debutant_2_thermique.sauv' ;
REST ;
 
 
* OBJET LOGIQUE POUR INDIQUER SI L'ON FAIT LES TRACES OU NON
* ----------------------------------------------------------
ITRAC    = FAUX ;
 
 
* CARACTERISTIQUES MECANIQUES DU MATERIAU
* ---------------------------------------
YOUNGMAT = 30.E9 ;
NUMAT    = 0.2 ;
ALPHAMAT = 12.E-6 ;
SIGYMAT  = 120.E6 ;
 
 
 
 
 
 
************************************************************************
* CHAPITRE 5 : MECANIQUE ELASTIQUE LINEAIRE                            *
************************************************************************
 
 
* HYPOTHESE SUR LES DEFORMATIONS PLANES
* -------------------------------------
OPTI 'MODE' 'PLAN' 'DEFO' ;
 
 
* MODELE MECANIQUE A MATERIAU CONSTANT
* ------------------------------------
MOM1     = MODE SU 'MECANIQUE' 'ELASTIQUE' ;
MAM1     = MATE MOM1 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' ALPHAMAT 'TREF' T0 'TALP' T0 ;
 
 
* CALCUL DE LA MATRICE DE RAIDEUR
* -------------------------------
RI       = RIGI MOM1 MAM1 ;
 
 
* CONDITIONS AUX LIMITES: DEPLACEMENT IMPOSE
* ------------------------------------------
BLMX     = BLOQ PA   'UX' ;
BLMY     = BLOQ LBAS 'UY' ;
RITOT    = RI ET BLMX ET BLMY ;
 
 
* CONDITIONS AUX LIMITES: DENSITE SURFACIQUE ET VOLUMIQUE D'EFFORT
* ----------------------------------------------------------------
FS       = PRES 'MASS' MOM1 LHAUT 30.E6 ;
 
ROG      = MANU 'CHPO' SU 2 'FX' 0. 'FY' (-9.81 * RHOMAT) ;
FV       = CNEQ MOM1 ROG MAM1 ;
 
 
* CALCUL DU CHAMP DE DEPLACEMENT PAR APPEL AU SOLVEUR
* ---------------------------------------------------
U5       = RESO RITOT (FS ET FV) ;
 
 
* POST TRAITEMENT
* ---------------
* DEFORMEES
DEF_5    = DEFO SU U5 150. 'ROUG' ;
DEF_INI  = DEFO SU U5 0. ;
SI ITRAC ;
  TRAC (DEF_INI ET DEF_5) 'TITR' '[5] Deformee elastique sous compression uniforme' ;
FINSI ;
DEF_5C   = DEFO CSU U5 150. 'ROUG' ;
DEF_INIC = DEFO CSU U5 0. ;
SI ITRAC ;
  TRAC (DEF_INIC ET DEF_5C) 'TITR' '[5] Deformee du contour sous compression uniforme' ;
FINSI ;
 
 
* DEFORMATIONS
DEF      = EPSI U5 MOM1 'LINE' ;
 
 
* CONTRAINTES (PAR DEUX OPERATEURS => RESULTATS EQUIVALENTS)
SIG      = ELAS DEF MOM1 MAM1 ;
SIG      = SIGM U5  MOM1 MAM1 ;
SI ITRAC ;
  TRAC SIG MOM1 CSU 15 'TITR' '[5] Contraintes, compression uniforme' ;
FINSI ;
DEF_5B   = DEFO SU U5 150. ;
SI ITRAC ;
  TRAC SIG MOM1 DEF_5B CSU 15 'TITR' '[5] Contraintes, compression uniforme, maillage deforme' ;
FINSI ;
 
 
* TRACE DES CONTRAINTES AUX POINTS DE GAUSS
SIGYY    = EXCO SIG 'SMYY' ;
MESS 'Mini et Maxi de Sigma YY : ' (MINI SIGYY)  (MAXI SIGYY) ;
SI ITRAC ;
  TRAC SIGYY MOM1 'TITR' '[5] Contrainte YY interpolee partout dans le maillage' ;
FINS ;
SIGYYG   = CHAN 'CHPO' SIGYY MOM1 'SUPP' ;
MPGAUSS  = EXTR SIGYYG 'MAIL' ;
SI ITRAC ;
  TRAC SIGYYG MPGAUSS 'TITR' '[5] Contrainte YY aux points de Gauss seulement' ;
FINS ;
 
 
* EVOLUTION DE LA CONCENTRATION DE CONTRAINTE DU TROU VERS LE BORD
SIGB     = CHAN 'CHPO' SIG MOM1 ;
LBASG    = LBAS ELEM 'COMP' PB PA ;
EVSIG    = EVOL 'CHPO' SIGB 'SMYY' LBASG ;
EVK      = (ABS EVSIG) / 30.E6 ;
SI ITRAC ;
  DESS EVK 'TITR' '[5] Concentration de contrainte le long de LBAS' ;
FINSI ;
 
 
* EVOLUTION DE LA CONTRAINTE LE LONG D'UNE LIGNE QUELCONQUE
OPTI 'ELEM' 'SEG2' ;
LIG1     = DROI 50 (0.1 0.1) (2.3 0.9) COUL 'ORAN' ;
SI ITRAC ;
  TRAC (CSU ET LIG1) 'TITR' '[5] Ligne quelconque LIG1' ;
FINS ;
SIGT     = CHAN 'NOEUD' MOM1 SIG ;
SIGLBAS  = PROI SIGT LIG1 ;
EVSIG2   = EVOL 'ORAN' 'CHPO' SIGLBAS 'SMXY' LIG1 ;
SI ITRAC ;
  DESS EVSIG2 'TITR' '[5] Contrainte XY le long de LIG1' ;
FINSI ;
 
 
* EFFORTS DE REACTION AUX APPUIS
REAC1    = REAC U5 (BLMX ET BLMY) ;
VREAC    = VECT REAC1 'FORC' 'ROUG' ;
VFIMP    = VECT FS 'FORC' 'VERT' ;
SI ITRAC ;
  TRAC (VFIMP ET VREAC) CSU 'TITR' '[5] Efforts imposes(V) et reactions aux appuis(R)' ;
FINSI ;
 
 
 
 
 
************************************************************************
* CHAPITRE 5.1 : MECANIQUE ELASTIQUE LINEAIRE                          *
*                EN DEPLACEMENTS IMPOSES                               *
************************************************************************
 
 
* MATRICES DE BLOCAGE
BLMY2    = BLOQ LHAUT 'UY' ;
RITOT2   = RI ET BLMX ET BLMY ET BLMY2 ;
 
 
* SECOND MEMBRE ASSOCIE AU BLOCAGE EN DEPLACEMENT NON NUL
FU       = DEPI BLMY2 -1.E-3 ;
 
 
* RESOLUTION
U52      = RESO RITOT2 (FU ET FV) ;
 
 
* POST TRAITEMENT
DEF_5C2  = DEFO CSU U52 150. 'VERT' ;
SI ITRAC ;
  TRAC (DEF_INIC ET DEF_5C ET DEF_5C2) 'TITR' '[5.1] Deformee du contour sous compression uniforme' ;
FINSI ;
 
 
 
 
 
 
 
 
 
 
************************************************************************
* CHAPITRE 6 : MECANIQUE ELASTIQUE LINEAIRE                            *
*              CHARGEMENT THERMIQUE                                    *
************************************************************************
 
 
* DEFORMATIONS THERMIQUES PURES AVEC LE DERNIER CHAMP DE TEMPERATURE
* DU CALCUL THERMIQUE AVEC CONVECTION + RAYONNEMENT
TFINAL   = TAB1 . 'TEMPERATURES' . (N1 - 1) ;
EPT      = EPTH TFINAL MOM1 MAM1 ;
 
 
* PSEUDO CONTRAINTES CORRESPONDANT A CES DEFORMATIONS THERMIQUES
* --------------------------------------------------------------
SIT      = ELAS EPT MOM1 MAM1 ;
 
 
* FORCES NODALES POUR CETTE DEFORMATION THERMIQUE
* -----------------------------------------------
FT       = BSIG SIT MOM1 ;
 
 
* DEPLACEMENTS, PAR APPEL AU SOLVEUR EN SUPERPOSANT LES FORCES
* PUREMENT MECANIQUES ET LES PSEUDO FORCES THERMIQUES
* ------------------------------------------------------------
U6       = RESO RITOT (FS ET FV ET FT) ;
 
 
* DEFORMEE THERMOMECANIQUE
* ------------------------
DEF_6    = DEFO SU  U6 150. ;
DEF_6C   = DEFO CSU U6 150. 'ORAN' ;
SI ITRAC ;
  TRAC (DEF_INIC ET DEF_5C ET DEF_6C) 'TITR' '[6] Deformees, compression seule(R), compression + temperature(O)' ;
FINSI ;
 
 
* DEFORMATIONS TOTALES
* --------------------
EP       = EPSI U6 MOM1 'LINE' ;
 
 
* DEFORMATIONS ELASTIQUES
* -----------------------
EPE      = EP - EPT ;
 
 
* LES CONTRAINTES SONT CALCULEES A PARTIR DES DEFORMATIONS ELASTIQUES
* -------------------------------------------------------------------
SIGT     = ELAS EPE MOM1 MAM1 ;
SI ITRAC ;
  TRAC SIGT MOM1 DEF_6 CSU 15 'TITR' '[6] Contraintes, compression + temperature' ;
FINSI ;
 
 
 
 
 
 
 
************************************************************************
* CHAPITRE 7 : MECANIQUE ELASTIQUE LINEAIRE                            *
*              CHARGEMENT THERMIQUE                                    *
*              MATERIAU VARIABLE DANS L'ESPACE                         *
************************************************************************
 
 
* ON REND LE COEFFICIENT DE DILATATION LINEAIRE ALPHA
* VARIABLE EN FONCTION DE LA COORDONNEE X
* ALPHA(X) = ALPHA0 * (1 + BETA*((X-XMOYEN)/(XMAX-XMIN))**3)
 
* RECUPERATION DE LA COORDONNEE X ET FORMATION D'UN
* CHAMP PAR POINTS (CHPOINT) PORTANT CETTE INFORMATION
* ----------------------------------------------------
XX       = COOR SU 1 ;
 
 
* VALEURS EXTREMES ET MOYENNE DE LA COORDONNEE X DU MAILLAGE
* ----------------------------------------------------------
XMAX     = MAXI XX ;
XMIN     = MINI XX ;
XMOY     = 0.5 * (XMAX + XMIN) ;
 
 
* CALCUL DU CHAMP PAR POINTS SCALAIRE DE ALPHA VARIABLE
* -----------------------------------------------------
BETA     = 7. ;
CHP_ALPH = ALPHAMAT * (1. + (BETA * (((XX - XMOY) / (XMAX - XMIN)) ** 3))) ;
 
 
* CONVERSION DU CHPOINT -> EN MCHAML
* ----------------------------------
CHM_ALPH = CHAN 'CHAM' CHP_ALPH MOM1 ;
 
 
* MISE A JOUR DU MCHAML DU MATERIAU AVEC ALPHA VARIABLE
* -----------------------------------------------------
MAM1B    = MATE MOM1 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' CHM_ALPH 'TREF' T0 'TALP' T0 ;
 
 
* MISE A JOUR DES DEFORMATIONS THERMIQUES PURES AVEC ALPHA VARIABLE
* -----------------------------------------------------------------
EPT      = EPTH TFINAL MOM1 MAM1B ;
 
 
* MISE A JOUR DES PSEUDO CONTRAINTES THERMIQUES AVEC ALPHA VARIABLE
* -----------------------------------------------------------------
SIT      = ELAS EPT MOM1 MAM1B ;
 
 
* MISE A JOUR DES FORCES NODALES POUR CETTE DEFORMATION THERMIQUE
* ---------------------------------------------------------------
FT       = BSIG SIT MOM1 ;
 
 
* DEPLACEMENTS AVEC ALPHA VARIABLE
* --------------------------------
U7       = RESO RITOT (FS ET FV ET FT) ;
 
 
* DEFORMEE AVEC ALPHA VARIABLE
* ----------------------------
DEF_7    = DEFO SU  U7 150. ;
DEF_7C   = DEFO CSU U7 150. 'ROUG' ;
SI ITRAC ;
  TRAC (DEF_INIC ET DEF_6C ET DEF_7C) 'TITR' '[7] Deformees, theromeca(O), + alpha var.(R)' ;
FINSI ;
 
 
* DEFORMATIONS TOTALES AVEC ALPHA VARIABLE
* ----------------------------------------
EP       = EPSI U7 MOM1 'LINE' ;
 
 
* DEFORMATION ELASTIQUES AVEC ALPHA VARIABLE
* ------------------------------------------
EPE      = EP - EPT ;
 
 
* CONTRAINTES AVEC ALPHA VARIABLE
* -------------------------------
SIGT     = ELAS EPE MOM1 MAM1B ;
SI ITRAC ;
  TRAC SIGT MOM1 DEF_7 CSU 15 'TITR' '[7] Contraintes, thermomeca, alpha var.' ;
FINSI ;
 
 
 
 
 
 
 
 
************************************************************************
* CHAPITRE 8 : MECANIQUE ELASTIQUE LINEAIRE ET PLASTIQUE PARFAIT       *
*              THERMIQUE TRANSITOIRE PRECEDENT (COND. + CONV. + RAYO.) *
*              MATERIAU VARIABLE DANS L'ESPACE                         *
************************************************************************
 
 
* MISE A JOUR DU MODELE MECANIQUE
* -------------------------------
MOM2     = MODE SU 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' ;
 
 
* MISE A JOUR DU MATERIAU (AJOUT DE LA LIMITE D'ELASTICITE 'SIGY')
* ----------------------------------------------------------------
CH2_ALPH = 'CHAN' 'CHAM' CHP_ALPH MOM2 ;
MAM2     = MATE MOM2 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' CH2_ALPH 'SIGY' SIGYMAT 'TREF' T0 'TALP' T0 ;
 
 
* DEFINITION DU CHARGEMENT MECANIQUE INCREMENTAL
* ----------------------------------------------
* NOTA : EN PLASTICITE ON NE PEUT GENERALEMENT PAS APPLIQUER
*        BRUTALEMENT UN CHARGEMENT FINAL POUR LEQUEL IL Y AURAIT
*        DEPASSEMENT EXCESSIF DE LA LIMITE D'ELASTICITE DES LA
*        PREMIERE ITERATION DU CALCUL NON LINEAIRE ITERATIF
 
* EVOLUTIONS TEMPORELLES DES CHARGEMENTS MECANIQUES
* -------------------------------------------------
EVTM     = EVOL 'MANU' 'Temps' (PROG 0. (0.98 * TPSFIN) TPSFIN)
                       'Coef'  (PROG 0.  0.             1.) ;
CHAFS    = CHAR 'MECA' FS EVTM ;
CHAFV    = CHAR 'MECA' FV EVCTE ;
CHAM     = CHAFS ET CHAFV ;
 
 
* PREPARATION DE LA TABLE POUR PASAPAS
* ------------------------------------
TAB2                         = TABL ;
TAB2 . 'MODELE'              = MOT ET MOC ET MOR ET MOM2 ;
TAB2 . 'CARACTERISTIQUES'    = MAT ET MAC ET MAR ET MAM2 ;
TAB2 . 'BLOCAGES_MECANIQUES' = BLMX ET BLMY ;
TAB2 . 'BLOCAGES_THERMIQUES' = BLT ;
TAB2 . 'CHARGEMENT'          = CHAT ET CHAM ;
TAB2 . 'TEMPS_CALCULES'      = PROG 0. 'PAS' (0.02 * TPSFIN)  (0.98 * TPSFIN)
                                       'PAS' (0.001 * TPSFIN) TPSFIN ;
TAB2 . 'CELSIUS'             = VRAI ;
 
 
* APPEL A PASAPAS
* ---------------
PASAPAS TAB2 ;
 
 
* POST TRAITEMENT
* ---------------
* COMPARAISON DE LA DEFORMEE FINALE AVEC LES CALCULS PRECEDENTS
N2       = DIME (TAB2 . 'DEPLACEMENTS') ;
U8       = TAB2 . 'DEPLACEMENTS' . (N2 - 1) ;
DEF_8    = DEFO SU  U8 150. ;
DEF_8C   = DEFO CSU U8 150. 'VIOL' ;
SI ITRAC ;
  TRAC (DEF_INIC ET DEF_7C ET DEF_8C) 'TITR' '[8] Deformees, elas.(R), + plas.(V)' ;
FINSI ;
 
* BOUCLE SUR LES PAS DE TEMPS ET TRACE DES CONTRAINTES ET DE LA
* DEFORMATION PLASTIQUE EQUIVALENTE CUMULEE
LISO2    = PROG 0. 'PAS' 10.E6 100.E6 ;
SI ITRAC ;
  REPE B1 N2 ;
    TPS_I    = TAB2 . 'TEMPS' . (&B1 - 1) ;
    U_I      = TAB2 . 'DEPLACEMENTS' . (&B1 - 1) ;
    DEF_I    = DEFO SU U_I 150. ;
    S_I      = TAB2 . 'CONTRAINTES' . (&B1 - 1) ;
    PRC_I    = ENTI (100. * TPS_I / TPSFIN) ;
    MOT_I    = CHAI '[8] Contraintes au temps ' TPS_I '  (' PRC_I ' %)' ;
    TRAC S_I MOM2 DEF_I CSU LISO2 'TITR' MOT_I ;
  FIN B1 ;
  VI       = TAB2 . 'VARIABLES_INTERNES' . (N2 - 1) ;
  EQ_MAX   = MAXI (EXCO 'EPSE' VI) ;
  LISO3    = PROG 0. 'PAS' (EQ_MAX / 10.) EQ_MAX ;
  REPE B1 N2 ;
    TPS_I    = TAB2 . 'TEMPS' . (&B1 - 1) ;
    U_I      = TAB2 . 'DEPLACEMENTS' . (&B1 - 1) ;
    DEF_I    = DEFO SU U_I 150. ;
    V_I      = TAB2 . 'VARIABLES_INTERNES' . (&B1 - 1) ;
    PRC_I    = ENTI (100. * TPS_I / TPSFIN) ;
    MOT_I    = CHAI '[8] Def. plas. eq. cumulee au temps ' TPS_I '  (' PRC_I ' %)' ;
    TRAC V_I MOM2 DEF_I CSU LISO3 'TITR' MOT_I ;
  FIN B1 ;
FINSI ;
 
 
 
 
 
 
 
 
************************************************************************
* CHAPITRE 9 : MECANIQUE ELASTIQUE LINEAIRE ET PLASTIQUE PARFAIT       *
*              CHARGEMENT THERMIQUE                                    *
*              MATERIAU VARIABLE DANS L'ESPACE                         *
*              MATERIAU DEPENDANT DE LA TEMPERATURE                    *
************************************************************************
 
 
* VARIATION DE LA CONDUCTIVITE EN FONCTION DE T
* ---------------------------------------------
EVLAM    = EVOL 'MANU' 'T' (PROG 50. 200.) 'K' (PROG 210. 250.) ;
 
 
* MISE A JOUR DU MATERIAU
* -----------------------
MAT2     = MATE MOT 'K' EVLAM 'C' CAPAMAT 'RHO' RHOMAT 'TINI' T0 ;
 
 
* MISE A JOUR DES DONNEES D'ENTREE DANS LA TABLE DE PASAPAS
* ----------------------------------------------------------
TAB2                         = TABL ;
TAB2 . 'MODELE'              = MOT  ET MOC ET MOR ET MOM2 ;
TAB2 . 'CARACTERISTIQUES'    = MAT2 ET MAC ET MAR ET MAM2 ;
TAB2 . 'BLOCAGES_MECANIQUES' = BLMX ET BLMY ;
TAB2 . 'BLOCAGES_THERMIQUES' = BLT ;
TAB2 . 'CHARGEMENT'          = CHAT ET CHAM ;
TAB2 . 'TEMPS_CALCULES'      = PROG 0. 'PAS' (0.02 * TPSFIN)  (0.98 * TPSFIN)
                                       'PAS' (0.001 * TPSFIN) TPSFIN ;
TAB2 . 'CELSIUS'             = VRAI ;
 
 
* APPEL A PASAPAS
* ---------------
PASAPAS TAB2 ;
 
 
* POST TRAITEMENT
* ---------------
* COMPARAISON DE LA DEFORMEE FINALE AVEC LES CALCULS PRECEDENTS
N2       = DIME (TAB2 . 'DEPLACEMENTS') ;
U9       = TAB2 . 'DEPLACEMENTS' . (N2 - 1) ;
DEF_9    = DEFO SU  U9 150. ;
DEF_9C   = DEFO CSU U9 150. 'BLEU' ;
MOT1     = CHAI '[9] Deformees, elas.(R), + plas.(V), + Sy var.(B)' ;
SI ITRAC ;
  TRAC (DEF_INIC ET DEF_7C ET DEF_8C ET DEF_9C) 'TITR' MOT1 ;
FINSI ;
 
* DEFORMATIONS PLASTIQUES CUMULEES
SI ITRAC ;
  VI       = TAB2 . 'VARIABLES_INTERNES' . (N2 - 1) ;
  EQ_MAX   = MAXI (EXCO 'EPSE' VI) ;
  LISO3    = PROG 0. 'PAS' (EQ_MAX / 10.) EQ_MAX ;
  REPE B1 N2 ;
    TPS_I    = TAB2 . 'TEMPS' . (&B1 - 1) ;
    U_I      = TAB2 . 'DEPLACEMENTS' . (&B1 - 1) ;
    DEF_I    = DEFO SU U_I 150. ;
    V_I      = TAB2 . 'VARIABLES_INTERNES' . (&B1 - 1) ;
    PRC_I    = ENTI (100. * TPS_I / TPSFIN) ;
    MOT_I    = CHAI '[9] Def. plas. eq. cumulee au temps ' TPS_I '  (' PRC_I ' %)' ;
    TRAC V_I MOM2 DEF_I CSU LISO3 'TITR' MOT_I ;
  FIN B1 ;
FINSI ;
 
 
FIN ;
 
 
 
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales